Como criar pacotes para o Arch Linux (parte 2) - pacotes svn e cvs

# Contributor: Hugo Doria <hugodoria@gmail.com>

# Use versionpkg to update.

pkgname=billreminder-svn
pkgver=335
pkgrel=1
pkgdesc='Small and quick accounting application designed to allow for easy tracking of bills'
arch=('i686' 'x86_64')
url='http://billreminder.sourceforge.net/'
depends=('python-pysqlite' 'python-notify' 'dbus-python' 'setuptools' 'desktop-file-utils' 'pygobject' 'pygtk')
makedepends=('subversion')
license=('MIT')
provides=('billreminder')
conflicts=('billreminder')
source=()
md5sums=()

_svntrunk=https://billreminder.svn.sourceforge.net/svnroot/billreminder
_svnmod=billreminder

build() {

    # Entra no diretório src. A variável $startdir, como o nome diz,
    # sempre indica o caminho inicial do pkgbuild.

    cd ${startdir}/src

    # Checa se existe o $_svnmod/.svn.
    # Se existir ele entrar no diretório e faz o update. Se não, ele faz tudo.

    if [ -d ${_svnmod}/.svn ]; then
    (cd ${_svnmod} && svn up -r ${pkgver})
    else
    svn co ${_svntrunk} --config-dir ./ -r ${pkgver} ${_svnmod}
    fi

    # Mensagem para indicar que o checkout terminou e que vai começar o make

    msg 'SVN checkout done or server timeout'
    msg 'Starting make'

    # Faz uma cópia do $svnmod e entra nela. A construção é feita de lá.

    cp -r ${_svnmod} ${_svnmod}-build
    cd ${_svnmod}-build/trunk

    # Roda o comando necessário para se instalar o pacote. Aqui poderia ser, por exemplo: ./configure; #make; make install

    python setup.py install --root=${startdir}/pkg

    # Remove arquivos temporários

    rm -rf $startdir/src/${_svnmod}-build

}