tcsh (.tcshrc)

C shell personalizado

Categoria: Console

Software: tcsh

[ Hits: 7.562 ]

Por: Sandro Marcell


Algumas configurações bem úteis no meu dia-a-dia para o bom e velho C shell (tcsh), tais como correção e autocomplementação de comandos, prompt personalizado, histórico de comandos, aliases, além de diversas outras opções bem legais.


# .tcshrc - Arquivo de inicialização do C shell (tcsh)
# Sandro Marcell ([email protected])       
# Boa Vista, Roraima - 10/01/2008                    
# Criado sob a versão 6.14.0 do tcsh                

# Setando idioma pt_BR:
setenv 'LANG = pt_BR'
setenv 'LC_ALL = pt_BR'
setenv 'LC_TYPE = pt_BR'
setenv 'LC_MESSAGES = pt_BR'
# Caminho para executáveis:
set path=(/{bin,sbin} /usr/{bin,sbin} /usr/local/{bin,sbin} /usr/X11R6/bin)
# Caminho para manpages:
setenv MANPATH   /usr/man:/usr/{share,X11R6,local}/man
# Caminho para libs:
setenv LD_LIBRARY_PATH /usr/lib:/usr/{X11R6,local}/lib
# Sem checagem de e-mail:
unset mail
unsetenv HPATH
# Comando 'echo' no estilo System V:
set echo_style = sysv
# Ativando auto-cd (não há necessidade de uso do comando 'cd')
set implicitcd
# Modo de inserção:
set inputmode = insert
# Editor padrão no tcsh:
setenv EDITOR vim
# Limitando número máximo de processos:
limit maxproc 250
limit coredumpsize 0
# Ativando antialiasing para aplicações GTK e QT:
setenv 'GDK_USE_XFT = 1'
setenv 'QT_XFT = 1'

# Histórico:
set histfile = ~/.tcsh_history
set history  = 1000
set savehist = 1000
set histdup  = all

# Man pages coloridas:
if (-e `which most`) then
   setenv PAGER 'most -s'
   setenv LESSHISTFILE '-'
else
   setenv PAGER less
endif

# Prompt personalizado:
if ($uid != 0) then
   set prompt  = "%B%{\e[32m%}%n > %{\e[33m%}%S(%~)%s : %b"
   set prompt2 = "%B%{\e[37m%}=> %{\e[0m%}%b"
   set rprompt = "%B%S%{\e[36m%}%T%{\e[0m%}%s%b"
else
   set prompt  = "%B%S[%n]%s > %b"
   set prompt2 = "%B%{\e37m%}=> %{\e[0m%}%b"
   set rprompt = "%B%S%{\e[37m%}(%~)%{\e[0m%}%s%b"
endif

# Saída do comando 'ls' colorida:
set color
set colorcat
alias ls 'ls --color=auto'

# Simples Atalhos:
set rmstar              
alias ld 'ls -ld'       
alias lr 'ls -lR | more'       
alias free 'free -m'    
alias df 'df -hT'      
alias vim 'vim -i NONE'
alias rm 'rm -i'
alias mv 'mv -i'
alias cp 'cp -i'
alias cpu 'cat /proc/cpuinfo'
alias distro 'cat /etc/[A-Za-z]*[_-][rv]e[lr]* ; echo "Kernel `uname -r`"'
alias xterm 'xterm -ls -b 10 -bg black -fg green -cr white -fa times -fs 11'
alias aterm 'aterm -ls -tr +sb -fg green -cr white -tint white -sh 30'

# Teclas de atalho (sob o xterm):
bindkey ^[[3~ delete-char             # <DELETE>
bindkey ^[[2~ overwrite-mode          # <INSERT>
bindkey ^[[5~ history-search-backward # <PAGE UP> 
bindkey ^[[6~ history-search-forward  # <PAGE DOWN> 

# Procurando uma entrada específica no histórico:
bindkey ^A vi-search-back # <CTRL+A>
bindkey ^B vi-search-fwd  # <CTRL+B>

# Ativando auto-correção de comandos:
set autocorrect
set correct = all
set prompt3 = "tcsh: Corrigir para '%B%R%b' (y|n|e)?:"

# Auto-completando com <TAB>
set edit
set filec
set autolist
set autoexpand
set continue
set dunique
set fignore
set notify
set pushdsilent
set pushdtohome
set continue_args
set recexact
set wordchars
set complete = igncase
set matchbeep = ambiguous
set recognize_only_executables
# Fim
  


Comentários
[1] Comentário enviado por KelvinVicente em 25/06/2008 - 22:50h

caraca, isso é bem interessante, mas queria entender mais sobre o que cada comando faz =/
Pai Google será que vai ajudar um tanto? XD


Contribuir com comentário

  



Patrocínio

Site hospedado pelo provedor RedeHost.
Linux banner
Linux banner

Destaques

Artigos

Dicas

Tópicos

Top 10 do mês

Scripts